我对Haskell'length'函数的重新定义将不起作用

由 lipsum发布于 2020-04-03 00:45:02

有人可以解释一下我如何修复程序。对于Haskell来说，这是非常新的东西，它一直试图创建一个长度函数来计算任何类型的列表的长度。

我的目标是使用“数据”来做到这一点，因为我想创建一个全新的类型来做到这一点（这是我目前正在学习的Haskell领域，这就是为什么它可能不是此功能的最有效实现））

data List a = Nil | Cons a (List a)


len :: List a -> Int
len Nil         = 0
len (Cons _ xs) = 1 + len xs

If I run it on len [1,2,3] I get the error:

 • Couldn't match expected type ‘List a0’
                  with actual type ‘[Integer]’
    • In the first argument of ‘len’, namely ‘[1, 2, 3]’
      In the expression: len [1, 2, 3]
      In an equation for ‘it’: it = len [1, 2, 3]

洛可可

2020-04-03 00:45:02

The function definition is correct, but [1,2,3] is not a List a object, it is a [a] (or more canonical [] a). A list like [1,2,3] as List Int is:

len (Cons 1 (Cons 2 (Cons 3 Nil)))

Alternatively, you can make List a an instance of the IsList type class, and then use the -XOverloadedLists extension:

{-# LANGUAGE TypeFamilies #-}

import GHC.Exts(IsList(Item, fromList, toList))

instance IsList (List a) where
    type Item (List a) = a
    fromList = foldr Cons Nil
    toList Nil = []
    toList (Cons x xs) = x : toList xs

Then we can use the OverloadedLists extension:

$ ghci -XOverloadedLists -XTypeFamilies
GHCi, version 8.0.2: http://www.haskell.org/ghc/  :? for help
Loaded GHCi configuration from /home/kommusoft/.ghci
Prelude> data List a = Nil | Cons a (List a)
Prelude> import GHC.Exts(IsList(Item, fromList, toList))
Prelude GHC.Exts> :{
Prelude GHC.Exts| instance IsList (List a) where
Prelude GHC.Exts|     type Item (List a) = a
Prelude GHC.Exts|     fromList = foldr Cons Nil
Prelude GHC.Exts|     toList Nil = []
Prelude GHC.Exts|     toList (Cons x xs) = x : toList xs
Prelude GHC.Exts| :}
Prelude GHC.Exts> :{
Prelude GHC.Exts| len :: List a -> Int
Prelude GHC.Exts| len Nil         = 0
Prelude GHC.Exts| len (Cons _ xs) = 1 + len xs
Prelude GHC.Exts| :}
Prelude GHC.Exts> len [1,2,3]
3

lipsum

这家伙很懒，什么都没留下

积分
0
话题
0
评论
3144
注册排名
1481